msgpack23/CMakeLists.txt at main · rwindegger/msgpack23 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
cmake_minimum_required(VERSION 3.28)

project(msgpack23 LANGUAGES C CXX VERSION 3.2)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

include(GNUInstallDirs)

add_library(
        msgpack23
        INTERFACE
        include/msgpack23/msgpack23.h
)
add_library(msgpack23::msgpack23 ALIAS msgpack23)

# download CPM.cmake
file(
        DOWNLOAD
        https://github.com/cpm-cmake/CPM.cmake/releases/download/v0.40.8/CPM.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/cmake/CPM.cmake
        EXPECTED_HASH SHA256=78ba32abdf798bc616bab7c73aac32a17bbd7b06ad9e26a6add69de8f3ae4791
)
include(${CMAKE_CURRENT_BINARY_DIR}/cmake/CPM.cmake)

target_compile_features(msgpack23 INTERFACE cxx_std_23)

target_include_directories(
        msgpack23
        INTERFACE
        $<INSTALL_INTERFACE:include>
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
)

install(
        TARGETS msgpack23
        EXPORT msgpack23Targets
        DESTINATION ${CMAKE_INSTALL_LIBDIR}
)

install(
        DIRECTORY include/
        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

set(msgpack23_CMAKE_CONFIG_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/msgpack23")

install(
        EXPORT msgpack23Targets
        FILE msgpack23Targets.cmake
        NAMESPACE msgpack23::
        DESTINATION ${msgpack23_CMAKE_CONFIG_DESTINATION}
)

include(CMakePackageConfigHelpers)

write_basic_package_version_file(
        ${CMAKE_CURRENT_BINARY_DIR}/msgpack23ConfigVersion.cmake
        VERSION ${PROJECT_VERSION}
        COMPATIBILITY AnyNewerVersion
)
configure_package_config_file(
        ${CMAKE_CURRENT_LIST_DIR}/cmake/msgpack23Config.cmake.in
        ${CMAKE_CURRENT_BINARY_DIR}/msgpack23Config.cmake
        INSTALL_DESTINATION ${msgpack23_CMAKE_CONFIG_DESTINATION}
)

install(
        FILES
        ${CMAKE_CURRENT_BINARY_DIR}/msgpack23ConfigVersion.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/msgpack23Config.cmake
        DESTINATION ${msgpack23_CMAKE_CONFIG_DESTINATION}
)

export(
        EXPORT msgpack23Targets
        FILE ${CMAKE_CURRENT_BINARY_DIR}/msgpack23Targets.cmake
        NAMESPACE msgpack23::
)
export(PACKAGE msgpack23)

option(BUILD_TESTING "..." ON)
if (BUILD_TESTING)
    enable_testing()
    add_subdirectory(tests)
endif ()

option(BUILD_EXAMPLES "..." ON)
if (BUILD_EXAMPLES)
    add_subdirectory(examples)
endif()