gumdrop/meson.build at main · regularhunter/gumdrop · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
# SPDX-FileCopyrightText: 2025 Hunter Wardlaw
# SPDX-License-Identifier: GPL-3.0-or-later

project('gumdrop', 'rust',
  version: '0.1.1',
  license: ['GPL-3.0'],
  meson_version: '>= 0.59.0',
  default_options: [ 'warning_level=2', ],
)

dependency('gtk4', version: '>= 4.16.0')
dependency('libadwaita-1', version: '>= 1.5')
dependency('gstreamer-1.0', version: '>= 1.20')
dependency('gstreamer-audio-1.0', version: '>= 1.20')
dependency('gstreamer-play-1.0', version: '>= 1.20')
dependency('gstreamer-plugins-base-1.0', version: '>= 1.20')
dependency('gstreamer-plugins-bad-1.0', version: '>= 1.20')
dependency('gstreamer-bad-audio-1.0', version: '>= 1.20')

i18n = import('i18n')
gnome = import('gnome')
fs = import('fs')

cargo = find_program('cargo', required: true)

cargo_sources = files(
  'Cargo.toml',
  'Cargo.lock',
)

if get_option('profile') == 'development'
  profile = '.Devel'
  if fs.is_dir('.git')
    vcs_tag = run_command('git', 'rev-parse', '--short', 'HEAD', check: true).stdout().strip()
    if vcs_tag == ''
      version_suffix = '-devel'
    else
      version_suffix = '-@0@'.format(vcs_tag)
    endif
  else
    version_suffix = '-devel'
  endif
else
  profile = ''
  version_suffix = ''
endif

application_id = 'com.github.regularhunter.Gumdrop@0@'.format(profile)

subdir('data')
subdir('src')
subdir('po')

reuse = find_program('reuse', required: false)
if reuse.found()
  test('license',
    reuse,
    args:['lint'],
    workdir: meson.project_source_root(),
    suite: ['lint'],
  )
endif

test('lint',
  find_program('build-aux/checks.sh'),
  args: ['--tap'],
  protocol: 'tap',
  workdir: meson.project_source_root(),
  suite: ['lint'],
)

meson.add_dist_script(
  'build-aux/dist-vendor.sh',
  meson.project_source_root(),
  meson.project_build_root() / 'meson-dist' / '@0@-@1@'.format(meson.project_name(), meson.project_version()),
)

gnome.post_install(
  glib_compile_schemas: true,
  gtk_update_icon_cache: true,
  update_desktop_database: true,
)

summary({
    'prefix': get_option('prefix'),
    'libdir': get_option('libdir'),
    'datadir': get_option('datadir'),
    'bindir': get_option('bindir'),
  },
  section: 'Directories',
)

summary({
    'Profile': get_option('profile'),
  },
  section: 'Build options',
)