libela/meson.build at master · fbx/libela · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
project(
  'ela',
  'c',
  version: '0.3',
  license: 'MIT',
  default_options: [
    'warning_level=2',
    'werror=true',
  ],
)

cc = meson.get_compiler('c')

add_project_arguments(cc.get_supported_arguments([
  '-Wstrict-prototypes',
  '-Wmissing-prototypes',
  '-Wno-unused-parameter',
]), language: 'c')

libevent_dep = dependency('libevent')
rt_dep = cc.find_library('rt')

ela_files = []
ela_deps = [
  libevent_dep,
  rt_dep,
]

subdir('include')
subdir('src')

ela_inc = include_directories('include')

lib_ela = library(
  meson.project_name(), ela_files,
  version: meson.project_version(),
  dependencies: ela_deps,
  include_directories: [ela_inc],
  install: true,
)

ela_dep = declare_dependency(
  link_whole: lib_ela,
  include_directories: [ela_inc],
)

if get_option('tests')
  subdir('test')
endif

pkgconfig = import('pkgconfig')
pkgconfig.generate(lib_ela,
  version: meson.project_version(),
  filebase: meson.project_name(),
  name: meson.project_name(),
  description: 'Event loop abstraction library',
)