WrittenBooks/build.gradle at dev · ParchmentMC/WrittenBooks · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
plugins {
    id 'java-gradle-plugin'
    id 'org.parchmentmc.writtenbooks' version '0.+'
    id 'maven-publish'
}

project.group = 'org.parchmentmc'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.eclipse.jgit:org.eclipse.jgit:5.13.0.202109080827-r'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.7.1'
}

writtenbooks {
    githubRepo = 'ParchmentMC/WrittenBooks'
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(8)
    withSourcesJar()
}

test {
    useJUnitPlatform()
}

gradlePlugin {
    // Define the plugin
    plugins.register("writtenbooks") {
        id = 'org.parchmentmc.writtenbooks'
        implementationClass = 'org.parchmentmc.writtenbooks.WrittenBooksPlugin'
    }
}

publishing {
    publications.withType(MavenPublication).configureEach {
        pom {
            name = 'WrittenBooks'
            description = 'Gradle plugin for managing CI-related menial tasks.'
            organization {
                name = 'ParchmentMC'
                url = 'https://github.com/ParchmentMC'
            }
            licenses {
                license {
                    name = 'MIT'
                    url = 'https://opensource.org/licenses/MIT'
                }
            }
        }
    }
}