libphonenumber-android/build.gradle.kts at master · MichaelRocks/libphonenumber-android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
plugins {
  alias(libs.plugins.android.application) apply false
  alias(libs.plugins.android.library) apply false
  alias(libs.plugins.nmcp.aggregation)
  id("io.michaelrocks.publish-properties")
}

group = "io.michaelrocks"
version = "9.0.29"

tasks.register<Delete>("clean") {
  delete(rootProject.layout.buildDirectory)
}

tasks.register("integrationTest") {
  group = LifecycleBasePlugin.VERIFICATION_GROUP
  description = "Runs sample instrumentation tests on a Gradle-managed local Android device."
  dependsOn(":sample:pixel2Api30DebugAndroidTest")
}

nmcpAggregation {
  centralPortal {
    val centralPortalUsername = (findProperty("centralPortalUsername") as String?)
      ?: System.getenv("CENTRAL_PORTAL_USERNAME")
    val centralPortalPassword = (findProperty("centralPortalPassword") as String?)
      ?: System.getenv("CENTRAL_PORTAL_PASSWORD")

    if (centralPortalUsername != null && centralPortalPassword != null) {
      username = centralPortalUsername
      password = centralPortalPassword
    }

    publishingType = "AUTOMATIC"
  }
}

dependencies {
  // Explicitly list modules to publish to avoid breaking project isolation
  nmcpAggregation(project(":library"))
}