ygege-cloudfare/flake.nix at develop · Killianbe/ygege-cloudfare · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{
  description = "Ygégé - High-performance indexer for YGG Torrent";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        manifest = (pkgs.lib.importTOML ./Cargo.toml).package;
      in
      {
        packages.default = pkgs.rustPlatform.buildRustPackage {
          pname = manifest.name;
          version = manifest.version;

          src = pkgs.lib.cleanSource ./.;

          cargoLock = {
            lockFile = ./Cargo.lock;
          };

          nativeBuildInputs = with pkgs; [
            cmake
            perl
            pkg-config
            git
            rustPlatform.bindgenHook
          ];

          buildInputs = with pkgs; [
            openssl
          ];

          env = {
            BUILD_COMMIT = self.rev or "dirty";
            BUILD_DATE = "nix-build";
            BUILD_BRANCH = "nix";
          };

          doCheck = false;

          meta = with pkgs.lib; {
            description = manifest.description or "High-performance indexer for YGG Torrent";
            homepage = "https://github.com/UwUDev/ygege";
            license = licenses.mit;
            mainProgram = "ygege";
            platforms = platforms.linux;
          };
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ self.packages.${system}.default ];
          packages = with pkgs; [
            cargo
            rustc
            rust-analyzer
            clippy
            rustfmt
          ];
          LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";
        };
      }
    );
}