data-communication-process/build.gradle.kts at main · GroovyArea/data-communication-process · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
import org.gradle.api.tasks.testing.logging.TestLogEvent.STANDARD_ERROR
import org.gradle.api.tasks.testing.logging.TestLogEvent.STANDARD_OUT
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id("org.springframework.boot") version Dependency.springBootVersion
    id("io.spring.dependency-management") version Dependency.dependencyManagementVersion
    id("io.gitlab.arturbosch.detekt") version Dependency.detektVersion
    id("com.epages.restdocs-api-spec") version Dependency.restdocsapiSpecVersion
    kotlin("jvm") version Dependency.kotlinVersion
    kotlin("plugin.spring") version Dependency.kotlinVersion
    kotlin("plugin.jpa") version Dependency.kotlinVersion
    kotlin("plugin.allopen") version Dependency.kotlinVersion
    kotlin("plugin.noarg") version Dependency.kotlinVersion
    kotlin("kapt") version Dependency.kotlinVersion
}

allprojects {
    apply(plugin = "io.gitlab.arturbosch.detekt")
    apply(plugin = "kotlin")
    apply(plugin = "kotlin-kapt")
    apply(plugin = "org.jetbrains.kotlin.jvm")
    apply(plugin = "org.jetbrains.kotlin.plugin.jpa")
    apply(plugin = "org.jetbrains.kotlin.plugin.allopen")
    apply(plugin = "org.jetbrains.kotlin.plugin.noarg")

    group = Constant.GROUP_ID
    version = Constant.VERSION
    java.sourceCompatibility = JavaVersion.toVersion(Dependency.targetJvmVersion)

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(Dependency.targetJvmVersion)
        }
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        // kotlin
        implementation("org.jetbrains.kotlin:kotlin-reflect")
        implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.3")

        // Jackson
        implementation("com.fasterxml.jackson.module:jackson-module-kotlin")
        implementation("com.fasterxml.jackson.core:jackson-databind")

        // Coroutines
        implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:${Dependency.coroutineVersion}")
        implementation("org.jetbrains.kotlinx:kotlinx-coroutines-reactor:${Dependency.coroutineVersion}")

        // Spring MVC
        implementation("org.springframework.boot:spring-boot-starter-web")

        // Spring JPA
        implementation("org.springframework.boot:spring-boot-starter-validation")
        implementation("org.springframework.boot:spring-boot-starter-data-jpa")
        implementation("mysql:mysql-connector-java:${Dependency.mySQLConnectorVersion}")

        // Querydsl
        implementation("com.querydsl:querydsl-jpa:5.0.0:jakarta")
        kapt("com.querydsl:querydsl-apt:5.0.0:jakarta")
        kapt("org.springframework.boot:spring-boot-configuration-processor")

        annotationProcessor("jakarta.persistence:jakarta.persistence-api")
        annotationProcessor("jakarta.annotation:jakarta.annotation-api")

        // mapstruct
        implementation("org.mapstruct:mapstruct:${Dependency.mapstructVersion}")
        kapt("org.mapstruct:mapstruct-processor:${Dependency.mapstructVersion}")

        // detekt
        detektPlugins("io.gitlab.arturbosch.detekt:detekt-formatting:${Dependency.detektVersion}")

        // kotest
        testImplementation("io.kotest:kotest-runner-junit5:${Dependency.kotestVersion}")
        testImplementation("io.kotest.extensions:kotest-extensions-spring:${Dependency.kotestSprintExtensions}")
        testImplementation("io.mockk:mockk:${Dependency.mockkVersion}")

        // test
        testImplementation("org.mockito.kotlin:mockito-kotlin:4.1.0")
        testImplementation("org.mockito:mockito-inline:5.2.0")
    }


    tasks {
        withType<KotlinCompile> {
            kotlinOptions {
                freeCompilerArgs = listOf("-Xjsr305=strict")
                jvmTarget = Dependency.targetJvmVersion
            }
        }

        withType<Test> {
            useJUnitPlatform()

            testLogging {
                events(STANDARD_OUT, STANDARD_ERROR)

                showStandardStreams = true
                showCauses = true
                showStackTraces = true
            }
        }
    }

    allOpen {
        annotation("jakarta.persistence.Entity")
    }

    noArg {
        annotation("jakarta.persistence.Entity")
    }

    detekt {
        autoCorrect = true
    }
}